test(){
	deriv(A1 = - Cl * C - Cl2 * (C - C2))
	deriv(A2 = Cl2 * (C - C2))
	dosepoint(A1, idosevar = A1Dose)
	C = A1 / V
	C2 = A2 / V2
	error(CEps = 0.1)
	observe(CObs = C * (1 + CEps))
	stparm(V = tvV * exp(nV))
	stparm(V2 = tvV2 * exp(nV2))
	stparm(Cl = tvCl * exp(nCl))
	stparm(Cl2 = tvCl2 * exp(nCl2))
	fcovariate(WEIGHT)
	fcovariate(SEX())
	fixef(tvV = c(, 3739, ))
	fixef(tvV2 = c(, 2852, ))
	fixef(tvCl = c(, 210, ))
	fixef(tvCl2 = c(, 897, ))
	secondary(Ke = tvCl/tvV)
	secondary(K12 = tvCl2/tvV)
	secondary(K21 = tvCl2/tvV2)
	secondary(r1 = ((K12+K21+Ke)^2-4*K21*Ke)^0.5)
	secondary(Alpha = 0.5*(K12+K21+Ke+r1))
	secondary(Beta = 0.5*((K12+K21+Ke)-r1))
	secondary(A = (A1Dose/tvV*(Alpha-K21))/(Alpha-Beta))
	secondary(B = (-(A1Dose/tvV)*(Beta-K21))/(Alpha-Beta))
	secondary(AUC = A/Alpha+B/Beta)
	secondary(Cmax = A1Dose/tvV)
	secondary(AUMC = A/(Alpha*Alpha)+B/(Beta*Beta))
	secondary(MRT = AUMC/AUC)
	secondary(VSS = tvCl*MRT)
	secondary(Ke_hl = log(2)/Ke)
	secondary(Alpha_hl = log(2)/Alpha)
	secondary(Beta_hl = log(2)/Beta)
	ranef(diag(nV, nCl, nV2, nCl2) = c(1, 1, 1, 1))
}
