$PROB
# Model: `pk1cmt`
  - One-compartment PK model
      - Dual first-order absorption
      - Optional nonlinear clearance from `CENT`
  - Source: `mrgsolve` internal library
  - Date: `r Sys.Date()`
  - Version: `r packageVersion("mrgsolve")`

$PARAM @annotated @input
CL   :  1  : Clearance (volume/time)
V    : 20  : Central volume (volume)
KA   :  1  : Absorption rate constant 1 (1/time)

$PARAM @annotated
KA2  :  1  : Absorption rate constant 2 (1/time)
VMAX :  0  : Maximum velocity (mass/time)
KM   :  2  : Michaelis Constant (mass/volume)

$CMT @annotated
EV   : First extravascular compartment
CENT : Central compartment
EV2  : Second extravascular compartment

$GLOBAL
#define CP (CENT/V)
#define CLNL (VMAX/(KM+CP))

$ODE
dxdt_EV   = -KA*EV;
dxdt_EV2  = -KA2*EV2;
dxdt_CENT =  KA*EV + KA2*EV2 - (CL+CLNL)*CP;

$CAPTURE @annotated
CP : Plasma concentration (mass/volume)

$ENV
e <- ev(amt=100, ii=24, addl=9)
